Jazz Jackrabbit 2 Online

#include "MLLE-Include-1.8w.asc" ///@MLLE-Generated
#pragma require "ezjunk-MLLE-Data-2.j2l" ///@MLLE-Generated
#pragma require "ezjunk-MLLE-Data-1.j2l" ///@MLLE-Generated
#pragma require "ezjunk.j2t" ///@MLLE-Generated
#pragma require "Labrat1.j2t" ///@MLLE-Generated
#pragma require "ezjunk.j2l" ///@MLLE-Generated
#include "ArcaneWeapon9.asc" ///@MLLE-Generated
#pragma require "ArcaneWeapon9.asc" ///@MLLE-Generated
///@SaveAndRunArgs -server -capture ///@MLLE-Generated
const bool MLLESetupSuccessful = MLLE::Setup(array<MLLEWeaponApply@> = {null, null, null, null, null, null, null, ArcaneWeapons::FusionCannon::Weapon(), null});
#pragma require "Castle2.j2t"
#pragma require "Jungle1_1.00g.j2t"
#pragma require "CarrFixDay.j2t"

void onLevelLoad() {
	jjANIMATION@ anim = jjAnimations[jjAnimSets[ANIM::BRIDGE] + 6];
	for (uint j = 0; j < anim.frameCount; j++) {
		jjANIMFRAME@ frame = jjAnimFrames[anim + j];
		jjPIXELMAP sprite(frame);
		for (uint x = 0; x < sprite.width; ++x) {
			for (uint y = 0; y < sprite.height; ++y) {
				if (sprite[x,y] >= 88 && sprite[x,y] <= 94) sprite[x,y] = 224 + (sprite[x,y]&7)*int(1.5f);
			}
		}
		sprite.save(frame);
	}
	
	generateCustomSpringSprites(jjAnimSets[ANIM::CUSTOM[0]], array<uint> = {40});
	turnIntoCustomSpring(jjObjectPresets[OBJECT::FROZENSPRING], 0, 20.5f, false);
	
	jjObjectPresets[OBJECT::ONEUP].behavior = jjObjectPresets[OBJECT::GUN8AMMO3].behavior;
	jjObjectPresets[OBJECT::ONEUP].var[3] = WEAPON::GUN8 - 1;
	jjObjectPresets[OBJECT::ONEUP].eventID = OBJECT::GUN8AMMO3;
	jjPIXELMAP(0,0, 32,64, 5).trim().save(jjAnimFrames[jjObjectPresets[OBJECT::ONEUPBARREL].curFrame]);
	
	jjObjectPresets[OBJECT::ONEUPBARREL].behavior = FusionBarrel();
	
	for (int i = 1; i < 255; i++) {
		jjOBJ@ preset = jjObjectPresets[i];
		if (preset.playerHandling == HANDLING::PICKUP && preset.eventID != OBJECT::GUN8AMMO3 && preset.eventID != OBJECT::FULLENERGY) {
			preset.behavior = CannotBeBuried(preset.behavior);
		}
	}
	
	jjObjectPresets[OBJECT::RFPOWERUP].direction = 0;
	
	jjDelayGeneratedCrateOrigins = true;
}

jjANIMSET@ customSpringSprite;
array<int> fastCustomSpringSpeeds(jjLocalPlayerCount);
bool generateCustomSpringSprites(jjANIMSET@ anim, const array<uint> &in colors) {
	int length = colors.length();
	bool success = (@customSpringSprite = anim).allocate(array<uint>(length * 3, 5)) !is null;
	if (success) {
		uint srcSet = jjAnimSets[ANIM::SPRING];
		for (int i = 0; i < length; i++) {
			uint color = colors[i];
			uint destAnimOffset = anim + i * 3;
			for (int j = 0; j < 3; j++) {
				uint srcAnim = jjAnimations[srcSet + j];
				uint destAnim = jjAnimations[destAnimOffset + j];
				for (int k = 0; k < 5; k++) {
					jjPIXELMAP image(jjAnimFrames[destAnim + k] = jjAnimFrames[srcAnim + k]);
					int width = image.width;
					int height = image.height;
					for (int l = 0; l < height; l++) {
						for (int m = 0; m < width; m++) {
							int pixel = image[m, l];
							if (pixel >= 32 && pixel < 40)
								image[m, l] = color + (pixel & 7);
						}
					}
					if (!image.save(jjAnimFrames[destAnim + k]))
						return false;
				}
			}
		}
	}
	return success;
}
void initializeCustomSpring(jjOBJ@ obj) {
	int anim = obj.curAnim;
	obj.behave(obj.behavior = BEHAVIOR::SPRING, false);
	if (obj.curAnim != anim) {
		obj.curAnim = anim + 2;
		obj.determineCurFrame();
	}
	obj.draw();
}
void turnIntoCustomSpring(jjOBJ@ obj, uint color, float power, bool horizontal) {
	if (horizontal) {
		obj.xSpeed = power;
		obj.ySpeed = 0.f;
	} else {
		obj.xSpeed = 0.f;
		obj.ySpeed = -power;
		if (obj.state == STATE::START && obj.creatorType == CREATOR::LEVEL) {
			int x = int(obj.xPos) >> 5;
			int y = int(obj.yPos) >> 5;
			if (jjParameterGet(x, y, 0, 1) != 0) {
				jjParameterSet(x, y, 0, 1, 0);
				obj.yPos -= 4.f;
				obj.ySpeed = power;
			}
		}
	}
	obj.behavior = initializeCustomSpring;
	obj.curAnim = customSpringSprite + color * 3 + (horizontal ? 1 : 0);
	obj.energy = obj.frameID = obj.freeze = obj.justHit = obj.light = obj.points = 0;
	obj.isBlastable = obj.isTarget = obj.scriptedCollisions = obj.triggersTNT = false;
	obj.deactivates = obj.isFreezable = true;
	obj.bulletHandling = HANDLING::IGNOREBULLET;
	obj.playerHandling = HANDLING::SPECIAL;
	obj.lightType = LIGHT::NORMAL;
	obj.determineCurFrame();
}

class CannotBeBuried : jjBEHAVIORINTERFACE {
	CannotBeBuried(const jjBEHAVIOR &in behavior) {
		originalBehavior = behavior;
	}
	void onBehave(jjOBJ@ obj) {
		obj.behave(originalBehavior);
		if (jjMaskedPixel(int(obj.xPos), int(obj.yPos + 8))) {
			obj.state = STATE::FLOAT;
		}
	}
	bool onObjectHit(jjOBJ@ obj, jjOBJ@ bullet, jjPLAYER@ player, int force) {
		if (bullet is null) {
			obj.behavior = originalBehavior;
			if (player.objectHit(obj, force, obj.playerHandling))
				return true;
			obj.behavior = this;
		}
		return false;
	}
	private jjBEHAVIOR originalBehavior;
}

class FusionBarrel : jjBEHAVIORINTERFACE {
	void onBehave(jjOBJ@ obj) {
		if (obj.state == STATE::START) {
			obj.doesHurt = 2;
		}	
		if (obj.state == STATE::ACTION) {
			while (obj.doesHurt > 0) {
				jjOBJ@ extrapiece = jjObjects[jjAddObject(OBJECT::GUN8AMMO3, (obj.xPos-16) + jjRandom()%16, obj.yPos)];
				extrapiece.behavior = jjObjectPresets[OBJECT::GUN8AMMO3].behavior;
				extrapiece.counter = 560;
				extrapiece.state = STATE::FLOATFALL;
				
				obj.doesHurt--;
			}
		}
		obj.behave(BEHAVIOR::CRATE);
	}
}

void onLevelReload() {
	MLLE::SpawnOffgridsLocal();
	MLLE::ReapplyPalette();
}

bool onDrawAmmo(jjPLAYER@ player, jjCANVAS@ canvas) {
	return MLLE::WeaponHook.drawAmmo(player, canvas);
}

void onLevelBegin() {
	MLLE::SpawnOffgrids();
}

void onMain() {
	array<jjLAYER@> layers = jjLayerOrderGet();
	
	for (int i = 5; i <= 9; i++) {
		layers[i].hasTiles = !jjLowDetail;
	}
	
	for (int i = 5; i <= 17; i++) {
		if (!jjLowDetail) {
			layers[i].hasTiles = jjLayers[5].hasTiles;
		}
	}
	
	for (int i = 10; i <= 16; i++) {
		layers[i].xOffset += jjCos(jjGameTicks)/(48-i);
		layers[i].yOffset += jjCos(jjGameTicks)/(24-i);
	}

	for (int i = 1; i < jjObjectCount; i++) {
		if (jjObjects[i].eventID == OBJECT::GUN8AMMO3 && jjMaskedPixel(int(jjObjects[i].xPos), int(jjObjects[i].yPos + 8))) {
			jjObjects[i].state = STATE::FLOAT;
		}
	}
}