Downloads containing ezthorns.j2as

Downloads
Name Author Game Mode Rating
TSF with JJ2+ Only: Crown of ThornsFeatured Download PurpleJazz Battle 9.2 Download file

File preview

  1. const bool MLLESetupSuccessful = MLLE::Setup(array<MLLEWeaponApply@> = {null, null, null, se::FireworkMLLEWrapper(), null, null, null, WeaponVMega::Voranj::Weapon(), null}); ///@MLLE-Generated
  2. #include "MLLE-Include-1.5w.asc" ///@MLLE-Generated
  3. #pragma require "ezthorns-MLLE-Data-4.j2l" ///@MLLE-Generated
  4. #pragma require "ezthorns-MLLE-Data-3.j2l" ///@MLLE-Generated
  5. #pragma require "ezthorns-MLLE-Data-2.j2l" ///@MLLE-Generated
  6. #pragma require "ezthorns-MLLE-Data-1.j2l" ///@MLLE-Generated
  7. #pragma require "ezthorns.j2l" ///@MLLE-Generated
  8. #include "WeaponVMega8.asc" ///@MLLE-Generated
  9. #pragma require "WeaponVMega8.asc" ///@MLLE-Generated
  10. #include "SEfirework-mlle.asc" ///@MLLE-Generated
  11. #pragma require "SEfirework-mlle.asc" ///@MLLE-Generated
  12. #pragma require "rain9.wav"
  13. #pragma require "lightning2.wav"
  14. #pragma require "floorslide.wav"
  15. #pragma require "floorslideclose.wav"
  16.  
  17. int sample, time = 0;
  18. int lightningDelay = 90;
  19. float lightningOffset = 0;
  20. bool lightning, playOnceL, playOnceR = false;
  21. array<bool> stopwatch(4, false);
  22.  
  23. void onLevelLoad() {
  24.         jjUseLayer8Speeds = true;
  25.        
  26.         jjSetWaterLevel(89*32, true);
  27.         jjSetWaterGradient(40, 45, 35, 200, 240, 180);
  28.         jjWaterLighting = WATERLIGHT::GLOBAL;
  29.        
  30.         jjAnimSets[ANIM::UTERUS].load();
  31.         jjAnimations[jjAnimSets[ANIM::AMMO] + 59] = jjAnimations[jjAnimSets[ANIM::UTERUS] + 6];
  32.        
  33.         jjANIMATION@ anim = jjAnimations[jjAnimSets[ANIM::UTERUS] + 6];
  34.         for (uint j = 0; j < anim.frameCount; j++) {
  35.                 jjANIMFRAME@ frame = jjAnimFrames[anim + j];
  36.                 jjPIXELMAP sprite(frame);
  37.                 for (uint x = 0; x < sprite.width; ++x) {
  38.                         for (uint y = 0; y < sprite.height; ++y) {
  39.                                 if (sprite[x,y] >= 16 && sprite[x,y] <= 23 || (sprite[x,y] >= 80 && sprite[x,y] <= 87)) sprite[x,y] = 40 + (sprite[x,y]&7);
  40.                         }
  41.                 }
  42.                 sprite.save(frame);
  43.         }
  44.        
  45.         jjObjectPresets[OBJECT::ICEBULLET].xSpeed = jjObjectPresets[OBJECT::ICEBULLETPU].xSpeed = 11;
  46.         jjObjectPresets[OBJECT::ICEBULLET].var[6] = jjObjectPresets[OBJECT::ICEBULLETPU].var[6] = 16;
  47.         jjWeapons[WEAPON::ICE].gradualAim = true;
  48.        
  49.         jjObjectPresets[OBJECT::TOASTERPOWERUP].direction = 0;
  50.        
  51.         jjObjectPresets[OBJECT::TNT].killAnim = jjObjectPresets[OBJECT::BLASTERBULLET].killAnim;
  52.         jjObjectPresets[OBJECT::TNT].determineCurFrame();
  53.         jjObjectPresets[OBJECT::TNT].lightType = LIGHT::NONE;
  54.         jjObjectPresets[OBJECT::TNT].behavior = SpikeBomb();
  55.        
  56.         jjObjectPresets[OBJECT::COPTER].triggersTNT = false;
  57.         jjObjectPresets[OBJECT::COPTER].lightType = LIGHT::NONE;
  58.        
  59.         jjObjectPresets[OBJECT::STOPWATCH].behavior = SuperStopwatch();
  60.         jjObjectPresets[OBJECT::STOPWATCH].scriptedCollisions = true;
  61.        
  62.         for (int i = 0; i < 255; i++) {
  63.                 if (jjObjectPresets[i].behavior == BEHAVIOR::MONITOR) jjObjectPresets[i].triggersTNT = true;
  64.         }
  65.        
  66.         generateCustomSpringSprites(jjAnimSets[ANIM::CUSTOM[0]], array<uint> = {40, 88});
  67.         turnIntoCustomSpring(jjObjectPresets[OBJECT::FROZENSPRING], 0, 21.f, false);
  68.         turnIntoCustomSpring(jjObjectPresets[OBJECT::HORREDSPRING], 1, 28.5f, false);
  69.        
  70.         jjObjectPresets[OBJECT::HORREDSPRING].causesRicochet = false;
  71.         jjObjectPresets[OBJECT::HORREDSPRING].lightType = LIGHT::NONE;
  72.         jjObjectPresets[OBJECT::FROZENSPRING].lightType = LIGHT::NONE;
  73.        
  74.         jjPIXELMAP rain(32,32);
  75.         for (uint x = 0; x < rain.width; ++x) {
  76.                 for (uint y = 0; y < rain.height; ++y) {
  77.                         if (x == 16) {
  78.                                 if (y <= 16) rain[x,y] = 76;
  79.                                 else if (y > 16 && y <= 24) rain[x,y] = 75;
  80.                                 else rain[x,y] = 0;
  81.                         } else {
  82.                                 rain[x,y] = 0;
  83.                         }
  84.                 }
  85.         }
  86.                
  87.         jjANIMATION@ animRain = jjAnimations[jjAnimSets[ANIM::COMMON].firstAnim + 2];
  88.         for (uint frameID = 0; frameID < animRain.frameCount; ++frameID) {
  89.                 jjANIMFRAME@ frame = jjAnimFrames[animRain.firstFrame + frameID];
  90.                 rain.save(frame);
  91.                 frame.hotSpotX = -frame.width/2;
  92.                 frame.hotSpotY = -frame.height;
  93.         }
  94. }
  95.  
  96. jjANIMSET@ customSpringSprite;
  97. array<int> fastCustomSpringSpeeds(jjLocalPlayerCount);
  98. bool generateCustomSpringSprites(jjANIMSET@ anim, const array<uint> &in colors) {
  99.         int length = colors.length();
  100.         bool success = (@customSpringSprite = anim).allocate(array<uint>(length * 3, 5)) !is null;
  101.         if (success) {
  102.                 uint srcSet = jjAnimSets[ANIM::SPRING];
  103.                 for (int i = 0; i < length; i++) {
  104.                         uint color = colors[i];
  105.                         uint destAnimOffset = anim + i * 3;
  106.                         for (int j = 0; j < 3; j++) {
  107.                                 uint srcAnim = jjAnimations[srcSet + j];
  108.                                 uint destAnim = jjAnimations[destAnimOffset + j];
  109.                                 for (int k = 0; k < 5; k++) {
  110.                                         jjPIXELMAP image(jjAnimFrames[destAnim + k] = jjAnimFrames[srcAnim + k]);
  111.                                         int width = image.width;
  112.                                         int height = image.height;
  113.                                         for (int l = 0; l < height; l++) {
  114.                                                 for (int m = 0; m < width; m++) {
  115.                                                         int pixel = image[m, l];
  116.                                                         if (pixel >= 32 && pixel < 40)
  117.                                                                 image[m, l] = color + (pixel & 7);
  118.                                                 }
  119.                                         }
  120.                                         if (!image.save(jjAnimFrames[destAnim + k]))
  121.                                                 return false;
  122.                                 }
  123.                         }
  124.                 }
  125.         }
  126.         return success;
  127. }
  128. void initializeCustomSpring(jjOBJ@ obj) {
  129.         int anim = obj.curAnim;
  130.         obj.behave(obj.behavior = BEHAVIOR::SPRING, false);
  131.         if (obj.curAnim != anim) {
  132.                 obj.curAnim = anim + 2;
  133.                 obj.determineCurFrame();
  134.         }
  135.         obj.draw();
  136. }
  137. void turnIntoCustomSpring(jjOBJ@ obj, uint color, float power, bool horizontal) {
  138.         if (horizontal) {
  139.                 obj.xSpeed = power;
  140.                 obj.ySpeed = 0.f;
  141.         } else {
  142.                 obj.xSpeed = 0.f;
  143.                 obj.ySpeed = -power;
  144.                 if (obj.state == STATE::START && obj.creatorType == CREATOR::LEVEL) {
  145.                         int x = int(obj.xPos) >> 5;
  146.                         int y = int(obj.yPos) >> 5;
  147.                         if (jjParameterGet(x, y, 0, 1) != 0) {
  148.                                 jjParameterSet(x, y, 0, 1, 0);
  149.                                 obj.yPos -= 4.f;
  150.                                 obj.ySpeed = power;
  151.                         }
  152.                 }
  153.         }
  154.         obj.behavior = initializeCustomSpring;
  155.         obj.curAnim = customSpringSprite + color * 3 + (horizontal ? 1 : 0);
  156.         obj.energy = obj.frameID = obj.freeze = obj.justHit = obj.light = obj.points = 0;
  157.         obj.isBlastable = obj.isTarget = obj.scriptedCollisions = obj.triggersTNT = false;
  158.         obj.deactivates = obj.isFreezable = true;
  159.         obj.bulletHandling = HANDLING::IGNOREBULLET;
  160.         obj.playerHandling = HANDLING::SPECIAL;
  161.         obj.lightType = LIGHT::NORMAL;
  162.         obj.determineCurFrame();
  163. }
  164.  
  165. class SpikeBomb : jjBEHAVIORINTERFACE {
  166.         int timer = 0;
  167.         void onBehave(jjOBJ@ obj) {
  168.                 obj.behave(BEHAVIOR::TNT);
  169.                
  170.                 if (obj.counter == 1 && jjPlayers[obj.creatorID].isLocal && obj.state != STATE::EXPLODE) jjSample(obj.xPos, obj.yPos, SOUND::COMMON_FOEW2, 0, 0);
  171.                
  172.                 if (!jjMaskedHLine(int(obj.xPos - 12) , 24, int(obj.yPos + 8))) {
  173.                         obj.yPos += 5;
  174.                 }
  175.                
  176.                 if (obj.state == STATE::EXPLODE) {
  177.                         if (obj.counter == 24) {
  178.                                 jjSample(obj.xPos, obj.yPos, SOUND::COMMON_PISTOL1, 0, 0);
  179.                                 for (int i = -8; i <= 8; i += 8) {
  180.                                         for (int j = -8; j <= 8; j += 8) {
  181.                                                 if (i != 0 || j != 0) {
  182.                                                         int id = jjAddObject(OBJECT::BULLET, obj.xPos, obj.yPos, obj.creatorID, CREATOR::PLAYER, BEHAVIOR::PEPPERBULLET);
  183.                                                         if (id != 0) {
  184.                                                                 jjOBJ@ burst = jjObjects[id];
  185.                                                                 burst.animSpeed = 1;
  186.                                                                 burst.direction = obj.direction;
  187.                                                                 burst.determineCurAnim(ANIM::AMMO, 16);
  188.                                                                 burst.determineCurFrame();
  189.                                                                 burst.behavior = Spike();
  190.                                                                 burst.playerHandling = HANDLING::PLAYERBULLET;
  191.                                                                 burst.var[3] = 8;
  192.                                                                 burst.xSpeed = j;
  193.                                                                 burst.ySpeed = i;
  194.                                                                 burst.lightType = jjObjectPresets[OBJECT::BLASTERBULLET].lightType;
  195.                                                                 burst.light = jjObjectPresets[OBJECT::BLASTERBULLET].light;
  196.                                                                 burst.isBlastable = false;
  197.                                                         }
  198.                                                 }
  199.                                         }
  200.                                 }
  201.                         }
  202.                 }
  203.         }
  204. }
  205.  
  206. class Spike : jjBEHAVIORINTERFACE {
  207.         void onBehave(jjOBJ@ obj) {
  208.                 obj.behave(BEHAVIOR::PEPPERBULLET, obj.state == STATE::EXPLODE? true:false);
  209.                 obj.var[0] = int(atan2(-obj.ySpeed, obj.xSpeed) * (512.f * 0.318309886142228f));
  210.         }
  211.         void onDraw(jjOBJ@ obj) {
  212.                 if (obj.state != STATE::EXPLODE) jjDrawRotatedSpriteFromCurFrame(obj.xPos, obj.yPos, obj.curFrame, obj.var[0], 0.75, 0.75, SPRITE::NORMAL);
  213.         }
  214. }
  215.  
  216. class SuperStopwatch : jjBEHAVIORINTERFACE {
  217.         void onBehave(jjOBJ@ obj) {
  218.                 obj.behave(BEHAVIOR::PICKUP);
  219.         }
  220.         bool onObjectHit(jjOBJ@ obj, jjOBJ@ bull, jjPLAYER@ play, int force) {
  221.                 if (play !is null) {
  222.                         if (play.isLocal) {
  223.                                 stopwatch[play.localPlayerID] = true;
  224.                                 time = 60*70;
  225.                                 if (play.shieldTime > 0 && play.shieldType != SHIELD::NONE) play.shieldTime += 15*70;
  226.                                 jjSample(obj.xPos, obj.yPos, SOUND::COMMON_PICKUP1);
  227.                                 jjAlert("|||||You picked up the ||||||Super Stopwatch!  |||||(slows shield drain)");
  228.                         }
  229.                         obj.behavior = BEHAVIOR::EXPLOSION2;
  230.                         obj.scriptedCollisions = false;
  231.                         obj.frameID = 0;
  232.                 }
  233.                 return true;
  234.         }
  235. }
  236.  
  237. void onLevelReload() {
  238.         MLLE::Palette.apply();
  239. }
  240.  
  241. void onLevelBegin() {
  242.         for (int i = 1; i < 255; i++) {
  243.                 jjOBJ@ preset = jjObjectPresets[i];
  244.                 if (preset.playerHandling == HANDLING::PICKUP) {
  245.                         preset.behavior = CannotBeShotDown(preset.behavior);
  246.                 }
  247.         }
  248.        
  249.         jjSampleLoad(SOUND::WIND_WIND2A, "rain9.wav");
  250.         jjSampleLoad(SOUND::BILSBOSS_THUNDER, "lightning2.wav");
  251.         jjSampleLoad(SOUND::SCIENCE_PLOPKAOS, "floorslide.wav");
  252.         jjSampleLoad(SOUND::BONUS_BONUS1, "floorslideclose.wav");
  253. }
  254.  
  255. class CannotBeShotDown : jjBEHAVIORINTERFACE {
  256.         CannotBeShotDown(const jjBEHAVIOR &in behavior) {
  257.                 originalBehavior = behavior;
  258.         }
  259.         void onBehave(jjOBJ@ obj) {
  260.                 obj.behave(originalBehavior);
  261.                 if (obj.state == STATE::FLOATFALL)
  262.                         obj.state = STATE::FLOAT;
  263.         }
  264.         bool onObjectHit(jjOBJ@ obj, jjOBJ@ bullet, jjPLAYER@ player, int force) {
  265.                 if (bullet is null) {
  266.                         obj.behavior = originalBehavior;
  267.                         if (player.objectHit(obj, force, obj.playerHandling))
  268.                                 return true;
  269.                         obj.behavior = this;
  270.                 }
  271.                 return false;
  272.         }
  273.         private jjBEHAVIOR originalBehavior;
  274. }
  275.  
  276. void onPlayer(jjPLAYER@ play) {
  277.         array<jjLAYER@> layers = jjLayerOrderGet();
  278.         const int lightningLayer = layers.length - 4;
  279.         layers[lightningLayer].xOffset = lightningOffset;
  280.         if (jjGameTicks == 1) layers[lightningLayer].hasTiles = false;
  281.         if (!jjLowDetail) {
  282.                 if (lightning && lightningDelay > 0) lightningDelay--;
  283.                
  284.                 if (jjGameTicks % 1000 >= 940 && jjGameTicks % 1000 <= 979) {
  285.                         if (jjGameTicks % 5 == 0) {
  286.                                 layers[lightningLayer].hasTiles = true;
  287.                                 play.lighting = 145;
  288.                         }
  289.                         else {
  290.                                 layers[lightningLayer].hasTiles = false;
  291.                                 play.lighting = 125;
  292.                         }
  293.                
  294.                         if (jjGameTicks % 18 == 0) lightningOffset = jjRandom()%800;
  295.                 }
  296.                
  297.                 if (jjGameTicks % 1000 >= 980) {
  298.                         lightning = true;
  299.                         lightningDelay = 90;
  300.                 }
  301.                
  302.                 if (lightningDelay < 90) {
  303.                         play.lighting = 100;
  304.                 }
  305.                        
  306.                 if (lightning && lightningDelay == 0) {
  307.                         for (int i = 0; i < 2; i++) {
  308.                                 jjSample(play.xPos, play.yPos, SOUND::BILSBOSS_THUNDER, 41 + jjRandom()%22, 0);
  309.                         }
  310.                         lightning = false;
  311.                         lightningDelay = 90;
  312.                 }
  313.         } else {
  314.                 play.lighting = 100;
  315.                 layers[lightningLayer].hasTiles = false;
  316.         }
  317.         jjEnforceLighting = jjLowDetail? LIGHT::OPTIONAL : LIGHT::COMPLETE;
  318.         play.lightType = LIGHT::NONE;
  319.        
  320.         if (stopwatch[play.localPlayerID] && play.timerState == TIMER::STOPPED) play.timerStart(time);
  321.         if (!stopwatch[play.localPlayerID]) play.timerStop();
  322.         if (play.timerState == TIMER::STARTED && play.timerTime <= 3*70 && play.timerTime > 0 && play.timerTime % 70 == 0) jjSamplePriority(SOUND::COMMON_NOCOIN);
  323.         if (play.timerTime == 1) {
  324.                 stopwatch[play.localPlayerID] = false;
  325.         }
  326.         if (play.timerState == TIMER::STARTED && jjGameState == GAME::STOPPED) play.timerPause();
  327.         if (play.timerState == TIMER::PAUSED && jjGameState != GAME::STOPPED) play.timerResume();
  328.        
  329.         if (play.shieldTime > 15*70) play.shieldTime = 15*70;
  330.         if (stopwatch[play.localPlayerID] && jjGameTicks % 4 > 0 && jjGameState != GAME::STOPPED) play.shieldTime++;
  331.        
  332.         const int bounds = 24;
  333.        
  334.         if (play.xPos > ((jjLayerWidth[4]*32) - bounds) || play.xPos < bounds) {
  335.                 play.xPos = play.xPos < (bounds+1)? bounds : (jjLayerWidth[4]*32) - bounds;
  336.                 play.xSpeed = 0;
  337.                 play.specialMove = 0;
  338.         }
  339.        
  340.         if (play.health == 0) {
  341.                 time = play.timerTime;
  342.         }
  343. }
  344.  
  345. void onMain() {
  346.         for (int i = 1; i < jjObjectCount; i++) {
  347.                 jjOBJ@ obj = jjObjects[i];
  348.                 if (obj.isActive && obj.eventID == OBJECT::COPTER && obj.state == STATE::FLY) {
  349.                         obj.counter = 0;
  350.                         if (obj.var[4] == 0)
  351.                                 obj.state = STATE::DONE;
  352.                 }
  353.                 if (obj.behavior == BEHAVIOR::SPRING && obj.eventID != OBJECT::HORBLUESPRING) {
  354.                         obj.xPos = obj.xOrg + 16;
  355.                 }
  356.                 if (obj.eventID == OBJECT::WATERSHIELD) {
  357.                         obj.xPos = obj.xOrg - 16;
  358.                         obj.direction = 0;
  359.                 }
  360.                 if (obj.eventID == OBJECT::HORBLUESPRING) {
  361.                         obj.xPos = obj.xOrg - 8;
  362.                 }
  363.         }
  364.        
  365.         if (!jjLowDetail) {
  366.                 sample = jjSampleLooped(jjLocalPlayers[0].xPos, jjLocalPlayers[0].yPos, SOUND::WIND_WIND2A, sample, 24, 0);
  367.         }
  368.        
  369.         jjIsSnowing = !jjLowDetail;
  370.         for (int i = 0; i < 1024; i++) {
  371.                 jjPARTICLE@ particle = jjParticles[i];
  372.                 if (particle.type == PARTICLE::RAIN) {
  373.                         particle.xSpeed = 0;
  374.                         particle.ySpeed = jjLocalPlayers[0].ySpeed < 0? 10 : int(10 + jjLocalPlayers[0].ySpeed);
  375.                        
  376.                         if (jjTileGet(6, int(particle.xPos/32), int(particle.yPos/32)) != 0) {
  377.                                 particle.type = PARTICLE::INACTIVE;
  378.                         }
  379.                 }
  380.         }
  381.        
  382.         if (jjMaskedPixel(67*32, 50*32)) {
  383.                 if (!playOnceL) {
  384.                         jjSample(67*32, 50*32, SOUND::SCIENCE_PLOPKAOS, 60, 0);
  385.                         playOnceL = true;
  386.                 }
  387.         } else {
  388.                 if (playOnceL) {
  389.                         jjSample(67*32, 50*32, SOUND::BONUS_BONUS1, 50, 0);
  390.                         playOnceL = false;
  391.                 }
  392.         }
  393.        
  394.         if (jjMaskedPixel(74*32, 46*32)) {
  395.                 if (!playOnceR) {
  396.                         jjSample(74*32, 46*32, SOUND::SCIENCE_PLOPKAOS, 60, 0);
  397.                         playOnceR = true;
  398.                 }
  399.         } else {
  400.                 if (playOnceR) {
  401.                         jjSample(74*32, 46*32, SOUND::BONUS_BONUS1, 50, 0);
  402.                         playOnceR = false;
  403.                 }
  404.         }
  405.        
  406.         jjWaterLayer = jjLowDetail? 36:0;
  407. }
  408.  
  409.  
  410.  
  411. bool onDrawAmmo(jjPLAYER@ player, jjCANVAS@ canvas) {
  412.         return MLLE::WeaponHook.drawAmmo(player, canvas);
  413. }
  414.  
  415. bool onDrawPlayerTimer(jjPLAYER@ play, jjCANVAS@ canvas) {
  416.         if (stopwatch[play.localPlayerID]) {
  417.         canvas.drawString(
  418.                         jjSubscreenWidth - 73,
  419.                 jjSubscreenHeight - 284,
  420.                 "" + (play.timerTime + 70) / 70,
  421.                 STRING::LARGE,
  422.                 STRING::PALSHIFT,
  423.                 play.timerTime > 3*70?
  424.                         0 :
  425.                         jjGameTicks % 28 > 14?
  426.                                 -40 :
  427.                                 -24
  428.                 );
  429.                
  430.                 canvas.drawSprite(
  431.                         jjSubscreenWidth - 90,
  432.                         jjSubscreenHeight - 270,
  433.                         ANIM::PICKUPS,
  434.                         87,
  435.                         (jjGameTicks >> 2)/4
  436.                 );
  437.         }
  438.         return true;
  439. }