Jazz Jackrabbit 2 Online

const bool MLLESetupSuccessful = MLLE::Setup(array<MLLEWeaponApply@> = {WeaponVMega::Boomerang::Weapon(), DuoBouncers::Weapon(), null, null, null, null, null, null, null}); ///@MLLE-Generated
#include "MLLE-Include-1.8w.asc" ///@MLLE-Generated
#pragma require "xlmsail-MLLE-Data-3.j2l" ///@MLLE-Generated
#pragma require "xlmsail-MLLE-Data-2.j2l" ///@MLLE-Generated
#pragma require "xlmsail-MLLE-Data-1.j2l" ///@MLLE-Generated
#pragma require "xlmsail.j2l" ///@MLLE-Generated
#include "DuoBouncers.asc" ///@MLLE-Generated
#pragma require "DuoBouncers.asc" ///@MLLE-Generated
#include "WeaponVMega1.asc" ///@MLLE-Generated
#pragma require "WeaponVMega1.asc" ///@MLLE-Generated
///@SaveAndRunArgs -server -battle ///@MLLE-Generated
#include "limitedoxygen.asc"
#pragma require "seagulls.wav"
#pragma require "ezwharf_oceanwaves.ogg"

int waterHeight = 23.75*32;
int sample, sample2;
bool createFish = true;

array<OBJECT::Object> fishObjects = {
	OBJECT::APPLE, //0,
	OBJECT::BANANA, //1
	OBJECT::BURGER, //2
	OBJECT::CAKE, //3
	OBJECT::CANDY, //4
	OBJECT::CHERRY, //5
	OBJECT::CUPCAKE, //6
	OBJECT::DONUT, //7
	OBJECT::FRIES, //8
	OBJECT::GRAPES, //9
	OBJECT::HAM, //10
	OBJECT::THING //11
};

array<uint> fishToSpawn = {
	2,3,4,1,2,2,1,7,3,1,2,1
};

void onLevelLoad() {
	jjUseLayer8Speeds = true;
	jjSampleLoad(SOUND::P2_POEP, "empty.wav");
	jjLayers[1].spriteMode = SPRITE::BLEND_NORMAL;
	jjLayers[1].spriteParam = 200;
	jjLayers[2].spriteMode = SPRITE::BLEND_NORMAL;
	jjLayers[2].spriteParam = 255;
	
	jjSetWaterLevel(23.75*32,true);
	jjWaterLayer = 999;
	jjWaterLighting = WATERLIGHT::GLOBAL;
	water::maxOxygen = 800;

	jjObjectPresets[OBJECT::BOUNCERPOWERUP].behavior =
	NoFallMonitor;
	
	for (uint i = 0; i < fishObjects.length(); i++) {
	jjObjectPresets[fishObjects[i]].behavior = AmbientFish();
	jjObjectPresets[fishObjects[i]].special = i;
	}
	jjAnimSets[ANIM::FISH].load();
	jjObjectPresets[OBJECT::WEENIE].behavior = AmbientFish();
	
	jjObjectPresets[OBJECT::LEMON].behavior = FishSpawner();
	jjObjectPresets[OBJECT::LEMON].playerHandling = HANDLING::PARTICLE;
	jjObjectPresets[OBJECT::LEMON].bulletHandling = HANDLING::IGNOREBULLET;
	jjObjectPresets[OBJECT::LEMON].isBlastable = false;
	
	generateFishSprites(jjAnimSets[ANIM::CUSTOM[1]]);
	colorFishSprites(0, array<uint> = {32, 80, 48});
	colorFishSprites(1, array<uint> = {16, 40, 88});
	colorFishSprites(2, array<uint> = {24, 72, 40});
	colorFishSprites(3, array<uint> = {31, 56, 80});
	colorFishSprites(4, array<uint> = {40, 32, 48});
	colorFishSprites(5, array<uint> = {88, 32, 16});
	colorFishSprites(6, array<uint> = {72, 24, 40});
	colorFishSprites(7, array<uint> = {71, 64, 48});
	colorFishSprites(8, array<uint> = {48, 32, 88});
	colorFishSprites(10, array<uint> = {80, 16, 56});
	colorFishSprites(11, array<uint> = {56, 56, 56});
}

void generateFishSprites(jjANIMSET@ anim) {	
	uint srcSet = jjAnimSets[ANIM::FISH];
	anim.allocate(array<uint>(fishObjects.length(), 6));
	for (uint i = 0; i < fishObjects.length(); i++) {
		uint srcAnim = jjAnimations[srcSet + 1];
		uint destAnim = jjAnimations[anim + i];
		for (int j = 0; j < 6; j++) {
			jjPIXELMAP image(jjAnimFrames[destAnim + j] = jjAnimFrames[srcAnim + j]);
			image.save(jjAnimFrames[destAnim + j]);
		}
	}
}

void colorFishSprites(uint src, const array<uint> &in colors) {
    int length = colors.length();
	jjANIMATION@ anim = jjAnimations[jjAnimSets[ANIM::CUSTOM[1]] + src];
    for (int i = 0; i < 6; i++) {
        jjPIXELMAP image(jjAnimFrames[anim + i]);
        int width = image.width;
        int height = image.height;
        for (int y = 0; y < height; y++) {
            for (int x = 0; x < width; x++) {
                int pixel = image[x, y];
                if (pixel >= 32 && pixel < 40) {
					image[x, y] = colors[0] + (pixel & 7);
				}
				if (pixel >= 80 && pixel < 88) {
                    image[x, y] = colors[1] + (pixel & 7);
				}
				if (pixel >= 48 && pixel < 56) {
                    image[x, y] = colors[2] + (pixel & 7);
                }
            }
			image.save(jjAnimFrames[anim + i]);
        }
    }
}

class AmbientFish : jjBEHAVIORINTERFACE {
	float size, xOffset, yOffset;
	bool cosine;
	
	void onBehave(jjOBJ@ obj) {
		switch (obj.eventID) {
			case OBJECT::APPLE: 
				obj.xSpeed = 1;
				obj.ySpeed = 60;
				size = 1;
				xOffset = 48;
				yOffset = 24;
				cosine = true;
				break;
			case OBJECT::BANANA: 
				obj.xSpeed = 1.25;
				obj.ySpeed = 80;
				size = 0.85;
				xOffset = 24;
				yOffset = 16;
				cosine = false;
				break;
			case OBJECT::BURGER: 
				obj.xSpeed = 1.5;
				obj.ySpeed = 15;
				size = 0.75;
				xOffset = 48;
				yOffset = 24;
				cosine = true;
				break;
			case OBJECT::CAKE:
				obj.xSpeed = 0.75;
				obj.ySpeed = 25;
				size = 0.9;
				xOffset = 48;
				yOffset = 24;
				cosine = false;
				break;
			case OBJECT::CANDY:
				obj.xSpeed = 1.2;
				obj.ySpeed = 100;
				size = 0.8;
				xOffset = 48;
				yOffset = 24;
				cosine = true;
				break;
			case OBJECT::CHERRY:
				obj.xSpeed = 1.25;
				obj.ySpeed = 70;
				size = 0.75;
				xOffset = 48;
				yOffset = 24;
				cosine = false;
				break;
			case OBJECT::CUPCAKE:
				obj.xSpeed = 0.45;
				obj.ySpeed = 15;
				size = 0.9;
				xOffset = 88;
				yOffset = 64;
				cosine = true;
				break;
			case OBJECT::DONUT:
				obj.xSpeed = 2.5;
				obj.ySpeed = 140;
				size = 0.5;
				xOffset = 16;
				yOffset = 8;
				cosine = true;
				break;
			case OBJECT::FRIES:
				obj.xSpeed = 0.9;
				obj.ySpeed = 75;
				size = 1;
				xOffset = 48;
				yOffset = 24;
				cosine = true;
				break;
			case OBJECT::GRAPES:
				obj.xSpeed = 1;
				obj.ySpeed = 60;
				size = 0.7;
				xOffset = 48;
				yOffset = 24;
				cosine = false;
				break;
			case OBJECT::HAM:
				obj.xSpeed = 0.9;
				obj.ySpeed = 50;
				size = 1.1;
				xOffset = 56;
				yOffset = 32;
				cosine = true;
				break;
			case OBJECT::THING:
				obj.xSpeed = 0.5;
				obj.ySpeed = 10;
				size = 1.1;
				xOffset = 0;
				yOffset = 0;
				cosine = false;
				obj.lightType = LIGHT::LASER;
				obj.light = 15;
				break;
			case OBJECT::WEENIE:
				obj.xSpeed = 0.5;
				obj.ySpeed = 30;
				size = 1;
				xOffset = 0;
				yOffset = 0;
				cosine = false;
				break;
		}
		
		if (jjEventGet(int(obj.xPos/32), int(obj.yPos/32)) == AREA::PATH) {
			obj.direction *= -1;
		}
		
		if (obj.counter == 0) {
			obj.xPos = obj.xPos + (jjRandom()%2 == 0? xOffset:-xOffset);
			obj.yPos = obj.yPos + (jjRandom()%2 == 0? yOffset:-yOffset);
			if (jjEventGet(int(obj.xPos/32), int(obj.yPos/32)) == AREA::PATH) {
				obj.delete();
			}
			obj.direction = jjRandom()%2 == 0? 1:-1;
			obj.age = jjRandom()%6;
			obj.counter = 1;
		}
		
		obj.xPos = obj.xPos + (obj.age * 0.15 * obj.direction) + (obj.xSpeed * obj.direction);
		
		obj.bulletHandling = HANDLING::IGNOREBULLET;
		obj.playerHandling = HANDLING::PARTICLE;
		obj.deactivates = obj.triggersTNT = obj.isTarget = obj.isBlastable = obj.isFreezable = false;
		
		if (!inView(obj) || !createFish) {
			obj.delete();
		}
	}

	void onDraw(jjOBJ@ obj) {
		if (!jjLowDetail && createFish && inView(obj)) {
			jjDrawResizedSprite(
				int(obj.xPos),
				int(obj.yPos + (cosine? jjCos(jjGameTicks) * obj.ySpeed : jjSin(jjGameTicks) * obj.ySpeed)),
				obj.eventID == OBJECT::WEENIE? ANIM::PICKUPS : ANIM::CUSTOM[1],
				obj.eventID == OBJECT::WEENIE? 91 : obj.special,
				jjGameTicks / 10 % 6,
				size * obj.direction * (obj.eventID == OBJECT::WEENIE? -1:1),
				size,
				obj.eventID == OBJECT::THING || obj.eventID == OBJECT::WEENIE || jjColorDepth == 8? SPRITE::NORMAL : SPRITE::TINTED,
				152,
				10,
				10
			);
		}
	}
}

bool inView(const jjOBJ@ obj) {
	for (int i = 0; i < jjLocalPlayerCount; i++) {
		const jjPLAYER@ play = jjLocalPlayers[i];
		if (obj.xPos > play.cameraX - 512 && obj.yPos > play.cameraY - 256 && obj.xPos < play.cameraX + jjSubscreenWidth + 512 && obj.yPos < play.cameraY + jjSubscreenHeight + 256)
			return true;
	}
	return false;
}

class FishSpawner : jjBEHAVIORINTERFACE {
	void onBehave(jjOBJ@ obj) {
		if (obj.state == STATE::START && inView(obj) && createFish) {
			if (jjRandom()%400 == 0) {
				spawnFish(obj, (jjRandom()%4 == 0? OBJECT::WEENIE : OBJECT::THING), 1);
			} else {
				uint rand = jjRandom()%(fishObjects.length() - 1);
				if (rand == 6) {
					if (jjRandom()% 2 == 0) spawnFish(obj, fishObjects[rand], fishToSpawn[rand]);
				} else {
					spawnFish(obj, fishObjects[rand], fishToSpawn[rand]);
				}
				obj.state = STATE::DONE;
			}
		}
		if (!inView(obj) || !createFish) {
			obj.state = STATE::START;
		}
	}
	void spawnFish(jjOBJ@ obj, OBJECT::Object fishEvent, uint num) {
		for (uint i = 0; i < num; i++) {
			uint randX = int(obj.xPos - 192) + ((jjRandom()%32)*12);
			uint randY = int(obj.yPos - 64 + ((jjRandom()%32)*4));
			if (jjEventGet((randX/32), (randY/32)) != AREA::PATH) {
				jjOBJ@ fish = jjObjects[jjAddObject(fishEvent, randX, randY, obj.creatorID, CREATOR::OBJECT)];
			}
		}
	}
}

bool onDrawAmmo(jjPLAYER@ player, jjCANVAS@ canvas) {
	return MLLE::WeaponHook.drawAmmo(player, canvas);
}

void onLevelReload() {
	MLLE::SpawnOffgridsLocal();
	MLLE::ReapplyPalette();
}

void onPlayer(jjPLAYER@ player) {
	player.lightType = LIGHT::NONE;
	water::limitedOxygen(player);

	if (player.yPos >= 0) {
		int skill = jjParameterGet(uint16(player.xPos/32), uint16(player.yPos/32), -4, 2);	
		if (skill == 2) {
			if (jjLayers[1].spriteParam > 96) {
				jjLayers[1].spriteParam = jjLayers[1].spriteParam - 10;
			}
		}
		else if (jjLayers[1].spriteParam != 200) {
			jjLayers[1].spriteParam = jjLayers[1].spriteParam + 10;
		}
    }
	    if (player.yPos >= 0) {
		int skill = jjParameterGet(uint16(player.xPos/32), uint16(player.yPos/32), -4, 2);	
		if (skill == 2) {
			if (jjLayers[2].spriteParam > 96) {
				jjLayers[2].spriteParam = jjLayers[2].spriteParam - 10;
			}
		}
		else if (jjLayers[2].spriteParam != 255) {
			jjLayers[2].spriteParam = jjLayers[2].spriteParam + 10;
        }
	}
}

void NoFallMonitor(jjOBJ@ obj) {
	obj.direction = SPRITE::FLIPV;
	obj.behavior = BEHAVIOR::MONITOR;
	obj.behave();
	obj.direction = (jjRandom() & 1) == 1 ? SPRITE::FLIPV : SPRITE::FLIPHV;
}

void onLevelBegin() {
	MLLE::SpawnOffgrids();
	jjSampleLoad(SOUND::DOG_WAF1, "seagulls.wav");
	jjSampleLoad(SOUND::SCIENCE_PLOPKAOS, "ezwharf_oceanwaves.ogg");
	water::maxOxygen = 400;
		for (int i = 1; i < 255; i++) {
		jjOBJ@ preset = jjObjectPresets[i];
		if (preset.playerHandling == HANDLING::PICKUP) {
			preset.behavior = CannotBeShotDown(preset.behavior);
    }
	jjANIMATION@ animDopefish = jjAnimations[jjObjectPresets[OBJECT::WEENIE].curAnim];
	animDopefish.frameCount = 1;
	jjANIMFRAME@ frameDopefish = jjAnimFrames[animDopefish.firstFrame];
	jjPIXELMAP dopefish(114*32, 95*32, 32, 32, 4);
	dopefish.save(frameDopefish);
	frameDopefish.hotSpotX = -frameDopefish.width / 2;
	frameDopefish.hotSpotY = -frameDopefish.height / 2;
	}
	for (int i = 1; i < 255; i++) {
		jjOBJ@ preset = jjObjectPresets[i];
		if (preset.playerHandling == HANDLING::PICKUP) {
			preset.behavior = CannotBeShotDown(preset.behavior);
		}
	}
}


bool onDrawHealth(jjPLAYER@ play, jjCANVAS@ canvas) {
	water::drawOxygenTimer(play, canvas);
	return false;	
}

class CannotBeShotDown : jjBEHAVIORINTERFACE {
	CannotBeShotDown(const jjBEHAVIOR &in behavior) {
		originalBehavior = behavior;
	}
	void onBehave(jjOBJ@ obj) {
		obj.behave(originalBehavior);
		if (obj.state == STATE::FLOATFALL)
			obj.state = STATE::FLOAT;
	}
	bool onObjectHit(jjOBJ@ obj, jjOBJ@ bullet, jjPLAYER@ player, int force) {
		if (bullet is null) {
			obj.behavior = originalBehavior;
			if (player.objectHit(obj, force, obj.playerHandling))
				return true;
			obj.behavior = this;
		}
		return false;
	}
	private jjBEHAVIOR originalBehavior;
}

void onMain() {
	sample = jjSampleLooped(jjLocalPlayers[0].xPos, jjLocalPlayers[0].yPos, SOUND::DOG_WAF1, sample, jjLocalPlayers[0].yPos < 45*32? 32:24, 0);
	sample2 = jjSampleLooped(jjLocalPlayers[0].xPos, jjLocalPlayers[0].yPos, SOUND::SCIENCE_PLOPKAOS, sample2, jjLocalPlayers[0].yPos < 45*32? 32:24, 0);
}