Jazz Jackrabbit 2 Online

#pragma require "SuperToaster.asc"
#include "MLLE-Weapons.asc"

namespace SuperToaster {
	class Weapon : MLLEWeapons::WeaponInterface {
		Weapon() {
			super(
				regularObjectTemplate: MLLEWeapons::ObjectTemplate(
					xSpeed: 1,
					xAcc: 0.125,
					curAnim: jjAnimSets[ANIM::AMMO].firstAnim + 55,
					special: -1,
					var: array<int> = {0,0,0,0,0,0,2},
					lightType: LIGHT::FLICKER,
					light: 12,
					counterEnd: 35
				),
				powerupObjectTemplate: MLLEWeapons::ObjectTemplate(
					xSpeed: 1,
					xAcc: 0.125,
					animSpeed: 2,
					curAnim: jjAnimSets[ANIM::AMMO].firstAnim + 58,
					special: -1,
					var: array<int> = {0,0,0,0,0,0,2},
					lightType: LIGHT::FLICKER,
					light: 12,
					counterEnd: 35
				),
				spread: SPREAD::TOASTER,
				style: WEAPON::POPCORN,
				pickupAnimation: jjAnimSets[ANIM::AMMO] + 57,
				poweredUpPickupAnimation: jjAnimSets[ANIM::AMMO] + 56,
				powerupAnimation: jjAnimSets[ANIM::PICKUPS] + 65,
				ammoCrateAnimation: jjAnimSets[ANIM::PICKUPS] + 58,
				replacedByBubbles: true,
				multiplier: 12,
				gradualAim: true,
				traits: se::weapon_default_traits | se::weapon_melts_ice | se::weapon_fails_underwater,
				behavior: function(obj, powerup) { obj.behavior = Behavior; if (powerup) obj.eventID = OBJECT::TOASTERBULLETPU; DefaultWeapons::DefaultSample(obj, WEAPON::TOASTER); }
			);
		}
	}
	
	void Behavior(jjOBJ@ obj) {
		if (obj.state == STATE::START) obj.xSpeed = 5 * obj.direction;
		obj.behave(BEHAVIOR::TOASTERBULLET);
		if (obj.xSpeed != 0) obj.ySpeed += 0.085;
		
		if (obj.counter > 10) {
			jjPARTICLE@ cinders = jjAddParticle(PARTICLE::FIRE);
			if (cinders !is null) {
				cinders.xPos = int(obj.xPos - 8) + jjRandom()%17;
				cinders.yPos = int(obj.yPos - 8) + jjRandom()%17;
				cinders.fire.color = obj.eventID == OBJECT::TOASTERBULLETPU? 32:40;
				cinders.fire.colorStop = obj.eventID == OBJECT::TOASTERBULLETPU? 40:48;
				cinders.fire.colorDelta = 2;
			}
		}
	}
}